BottomLine

"Русская версия"

Description

The bottom expansion, when scrolling - doesn't change the position and expanding by induction of the mouse cursor.

BottomLine- in the bottom of page takes place the fixed bottomline which at a scrolling doesn't change the position. Expand to a flash-movie #2 occurs when inducting the mouse cursor on a flash-movie #1 without a delay. On a flash-movie #2 can be located the “Close button”, at a click on which the banner disappears from page.

Other names: CatFish.

Example

Example

Preparation (for developers)

Minimum requirements for the development environment (Authoring tool):

1. ActionScript 2.0 and FlashPlayer 8.0
2. ActionScript 3.0 and FlashPlayer 9.0

File size requirements

File size must not exceed the following
- Flash-movies (*. swf ) up to 300 Kb.

The limitations are checked separately for each file.   To use files that exceed those limits host them somewhere on your server and use URL field when creating the banner to provide a direct link to your file. (http://...)

File names
File names may only contain letters of English alphabet lower and upper case, numbers and ‘_’.   All other symbols such as russian letters,  space symbol and ‘“’ , ’”’, ‘-’ are not allowed.


Preparation on ActionScript 2.0

Flash-movie #1

1. Create a separate layer, name it adfoxTransitionButton

2. Create in this layer the transparent button and place it on the top layer. Appropriate to the button the name transitionButton

3. Copy a code and insert it into the first frame of the main timeline:

Stage.scaleMode = 'noScale';
Stage.align = 'TL';

var listener = new Object();
listener.onResize = stageResizeHandler;
Stage.addListener(listener);

var currentWidth:Number = Stage.width;
var currentHeight:Number = Stage.height;

function stageResizeHandler()
{
    currentWidth = Stage.width;
    currentHeight = Stage.height;
    resizeTransitionButton();
}
function resizeTransitionButton()
{
    transitionButton._width = currentWidth;
    transitionButton._height = currentHeight;
}
function initTransitionButton()
{
    transitionButton.onRelease = adfoxClickHandler;
    transitionButton.onRollOver = adfoxMouseOverHandler;
}
function initCloseButton()
{
    closeButton.onRelease = adfoxCloseHandler;
}
function adfoxMouseOverHandler()
{
    flash.external.ExternalInterface.call('adfoxOpen'+_root.bannerID);
}
function adfoxCloseHandler()
{
    flash.external.ExternalInterface.call('adfoxCloseAll'+_root.bannerID);
}
function adfoxClickHandler()
{
    getURL(_root.link1, _root.target);
}

initTransitionButton();

Flash-movie #2:

1. Create a separate layer, name it adfoxTransitionButton

2. Create in this layer the transparent button and place it on the top layer. Appropriate to the button the name transitionButton

3. Copy a code and insert it into the first frame of the main timeline:

Stage.scaleMode = 'noScale';
Stage.align = 'TL';

var listener = new Object();
listener.onResize = stageResizeHandler;
Stage.addListener(listener);

var currentWidth:Number = Stage.width;
var currentHeight:Number = Stage.height;

function stageResizeHandler()
{
    currentWidth = Stage.width;
    currentHeight = Stage.height;
    resizeTransitionButton();
}
function resizeTransitionButton()
{
    transitionButton._width = currentWidth;
    transitionButton._height = currentHeight;
}
function initTransitionButton()
{
    transitionButton.onRelease = adfoxClickHandler;
    transitionButton.onRollOut = adfoxMouseOutHandler; 
    transitionButton.onRollOver = function(){
        _root.canCollapce = true;
    }; 
}
function initCloseButton()
{
    closeButton.onRelease = adfoxCloseHandler;
    closeButton.onRollOver = function(){
        _root.canCollapce = false;
    };
}
function adfoxMouseOutHandler()
{
    setTimeout(function(){
        if(_root.canCollapce == true){
            flash.external.ExternalInterface.call('adfoxClose'+_root.bannerID);
        }
    },50)
}
function adfoxCloseHandler()
{
    flash.external.ExternalInterface.call('adfoxCloseAll'+_root.bannerID);
}
function adfoxClickHandler()
{
    getURL(_root.link1, _root.target);
}

initTransitionButton();
initCloseButton();

4. Place on the most top layer the Close button and name it closeButton.

Preparation on ActionScript 3.0

Flash-movie #1:

1. Create a separate layer, name it adfoxTransitionButton

2. Create in this layer the transparent button and place it on the top layer. Appropriate to the button the name transitionButton

3. Copy a code and insert it into the first frame of the main timeline:

import flash.external.ExternalInterface;
import flash.net.navigateToURL;
import flash.net.URLRequest;

if(stage)
{
    init();
}
else
{
    addEventListener(Event.ADDED_TO_STAGE, init);   
}

function init(evt:Event = null):void
{
    stage.scaleMode = 'noScale'; //Stretching banner;
    stage.align = 'TL';
    stage.addEventListener(Event.RESIZE, stageResizeHandler);

    var currentWidth:Number = stage.stageWidth,
    currentHeight:Number = stage.stageHeight,
    flashVars:Object = this.root.loaderInfo.parameters;

    function stageResizeHandler(evt:Event):void
    {
        currentWidth = stage.stageWidth;
        currentHeight = stage.stageHeight;
        resizeTransitionButton();
    }
    function resizeTransitionButton():void
    {
        transitionButton.width = currentWidth;
        transitionButton.height = currentHeight;
    }
    function initTransitionButton():void
    {
        transitionButton.addEventListener(MouseEvent.CLICK, adfoxClickHandler);
        transitionButton.addEventListener(MouseEvent.MOUSE_OVER, adfoxMouseOverHandler);
    }
    function adfoxMouseOverHandler(evt:MouseEvent):void
    {
        ExternalInterface.call('adfoxOpen'+flashVars.bannerID);
    }
    function adfoxClickHandler(evt:MouseEvent):void
    {
        navigateToURL(new URLRequest(flashVars.link1), flashVars.target);
    }

    initTransitionButton();
}

Flash-movie #2:

1. Create a separate layer, name it adfoxTransitionButton

2. Create in this layer the transparent button and place it on the top layer. Appropriate to the button the name** transitionButton**

3. Copy a code and insert it into the first frame of the main timeline:

import flash.external.ExternalInterface;
import flash.net.navigateToURL;
import flash.net.URLRequest;
import flash.utils.setTimeout;

if(stage)
{
    init();
}
else
{
    addEventListener(Event.ADDED_TO_STAGE, init);   
}
var canCollapce:Boolean = false;
function init(evt:Event = null):void
{
    stage.scaleMode = 'noScale'; //Stretching banner;
    stage.align = 'TL';
    stage.addEventListener(Event.RESIZE, stageResizeHandler);

    var currentWidth:Number = stage.stageWidth,
    currentHeight:Number = stage.stageHeight,
    flashVars:Object = this.root.loaderInfo.parameters;

    function stageResizeHandler(evt:Event):void
    {
        currentWidth = stage.stageWidth;
        currentHeight = stage.stageHeight;
        resizeTransitionButton();
    }
    function resizeTransitionButton():void
    {
        transitionButton.width = currentWidth;
        transitionButton.height = currentHeight;
    }
    function initTransitionButton():void
    {
        transitionButton.addEventListener(MouseEvent.CLICK, adfoxClickHandler);
        transitionButton.addEventListener(MouseEvent.MOUSE_OUT, adfoxMouseOutHandler);
        transitionButton.addEventListener(MouseEvent.MOUSE_OVER, function(e:MouseEvent):void{
            canCollapce = true;
        });
    }
    function initCloseButton():void
    {
        closeButton.addEventListener(MouseEvent.CLICK, adfoxCloseHandler);
        closeButton.addEventListener(MouseEvent.MOUSE_OVER, function(e:MouseEvent):void{
            canCollapce = false;
        });
    }
    function adfoxMouseOutHandler(evt:MouseEvent):void
    {
        setTimeout(function(){
            if(canCollapce == true){
                ExternalInterface.call('adfoxClose'+flashVars.bannerID);
            }
        },50);
    }
    function adfoxClickHandler(evt:MouseEvent):void
    {
        navigateToURL(new URLRequest(flashVars.link1), flashVars.target);
    }
    function adfoxCloseHandler(evt:MouseEvent):void
    {
        ExternalInterface.call('adfoxCloseAll'+flashVars.bannerID);
    }
    initTransitionButton();
    initCloseButton();
}

4. Place on the most top layer the Close button and name it closeButton.

Now it’s all ready.

Event counting

Event counting is implemented through AdFox variables event_1 ... event_30 which are also passed in FlashVars.

To count your particular event, you need to place this code whenever your event occurs:

• ActionScript 2.0

loadMovieNum(_root.event_N,300);

• ActionScript 3.0

import flash.net.sendToURL;
import flash.net.URLRequest;
var flashVars:Object = this.root.loaderInfo.parameters;
sendToURL(new URLRequest(flashVars.event_N));

where N-is the event number, N may be 1, 2 … 30.

Last update: 11.01.2013